Script som deler opp gjenstander

Max scripts

Moderatorer: Super Moderatorer, Admins

Brukeravatar

Trådstarter
tassel
Innlegg: 3987
Registrert: man 26 sep, 2005
Sted: Oslo
Kontakt:

Script som deler opp gjenstander

Legg innav tassel » ons 07 nov, 2007

Tatt fra posten til Drakon

Script som deler opp gjenstander

Kode: Velg alt

fn splitInTwo theObj theAngle =
(
local topObj = editable_mesh()
local bottomObj = editable_mesh()

centerPivot theObj
resetXForm theObj
convertToMesh theObj

topObj.transform = theObj.transform
bottomObj.transform = theObj.transform
topObj.mesh = theObj.mesh
bottomObj.mesh = theObj.mesh

topSlice = SliceModifier Slice_Type:2
bottomSlice = SliceModifier Slice_Type:3

topSlice.slice_plane.rotation = EulerAngles (random -theAngle theAngle) (random -theAngle theAngle) (random -theAngle theAngle)
bottomSlice.slice_plane.transform = topSlice.slice_plane.transform

addModifier topObj topSlice
addModifier bottomObj bottomSlice

capMod = cap_holes()
addModifier topObj capMod
addModifier bottomObj capMod
centerPivot topObj
centerPivot bottomObj
resetXform topObj
resetXform bottomObj
convertToMesh topObj
convertToMesh bottomObj

delete theObj
#(topObj, bottomObj)
)


sel = selection as array
for i = 1 to 20 do
(
sel = for o in sel where isValidNode o collect o
nextObj = sel[random 1 sel.count]
maxVolume = -1
for o in sel do
(
bbox = o.max - o.min
vol = bbox.x * bbox.y * bbox.z
if vol > maxVolume do
(
maxVolume = vol
nextObj = o
)
)
join sel (splitInTwo nextObj 45.0)
)

Copy paste inn i maxscript og gå File -> Evaluate all, da deler den opp gjenstanden som du da har selecta. eneste som er litt kjipt med det er at det deler i rette linjer, får en clean slice, noen ville kanskje foretrekke en mer røff og rotete (mer troverdig) split.

Gå tilbake til «Max scripts»

Hvem er online

Brukere i dette forumet: Ingen registrerte brukere og 1 gjest

cron