Hjelp: VFB Extended

Max scripts

Moderatorer: Super Moderatorer, Admins

Brukeravatar

Trådstarter
tassel
Innlegg: 3987
Registrert: man 26 sep, 2005
Sted: Oslo
Kontakt:

Hjelp: VFB Extended

Legg innav tassel » ons 27 feb, 2013

Hei,

Har holdt på en stund nå, men jeg gjør tydeligvis noe galt.
Er det noen av dere scripte guruer som klarer og få denne til å vise bildene med Gamma 2.2 ?

Kode: Velg alt


   try(destroyDialog vfbRoll)catch()
   
   rollout vfbRoll "VFB Extended"
   (
      button saveButt "Save" across:3
      button deleteButt "Delete"
      button clearButt "Clear"
      slider theSlide range:[1,1,1] type:#integer ticks:12
      
      progressbar theChoose "something" height:25
      
      imgTag theTag width:500 height:400 style:#bmp_center transparent:(color 500 500 500) pos:[0,100] bitmap:(bitmap 500 500 color:black) -- gamma:2.2
      
      
      --FUNCTIONS
      fn getTheFolder =
      (
         --return ((GetDir #renderOutput) + "/temp_VFB")
         return ("C:/temp/Renders/")
      )
      
      fn getTempRenders =
      (
         local theFolder = getTheFolder()
         makeDir theFolder
         return (getFiles (theFolder + "*.png"))
      )-- getTempRenders()
      
      fn setSlideRange =
      (
         local theVal = theSlide.value
         numFiles = (getTempRenders()).count
         theSlide.range = [ 1, numFiles, 1]
         theSlide.ticks = numFiles
         
         if theSlide.value <= theSlide.range[2] then
         (
            theSlide.value = theVal
         )
         else
         (
            theSlide.value = numFiles
         )
      )
      
      fn setTheBitmap =
      (
         try
         (
            local theVal = theSlide.value
            local theBmp = openBitMap (getTempRenders())[theVal]
            theTag.bitmap = theBmp
         )
         catch()
      )
      
      fn setTheBitmap2 =
      (
         try
         (
            local numFiles = (getTempRenders()).count
            local theVal =    ( (numFiles*theChoose.value/100.0+1) as integer )
            local theBmp = openBitMap (getTempRenders())[theVal]
            theTag.bitmap = theBmp
         )
         catch()
      )
      
      --EVENT HANDLERS
      
      on vfbRoll open do
      (
         setSlideRange()
         setTheBitmap()
      )
      
      on vfbRoll resized newSize do
      (
         theTag.width = newSize[1]
         theTag.height = newSize[2]
         
         print theSlide.ticks
      )
      
      on saveButt pressed do
      (
         try
         (
            local theBmp = theTag.bitmap
            local theName = getTheFolder() + ( ((getTempRenders()).count +1) as string ) + ".png"
            theBmp.filename = theName
            save theBmp
            setSlideRange()
            theSlide.value = theSlide.range[2]
         )
         catch()
      )
      
      on deleteButt pressed do
      (
         try
         (
            deleteFile theTag.bitmap.filename
            setSlideRange()
            setTheBitmap()
         )
         catch()
      )
      
      on theSlide changed theVal do
      (
         --setSlideRange()
         setTheBitmap()
      )
      
      on theChoose clicked newVal do
      (
         theChoose.value = newVal
         print newVal
         local numFiles = (getTempRenders()).count
         if newVal > 0 do
         (
            format "TheFile: % " ((numFiles*newVal/100.0+1) as integer)
         )
         
         setTheBitmap2()
      )
      
      on theTag dblclick do
      (
         theBmp = render outputsize:[theTag.width, theTag.height ] vfb:off
         theTag.bitmap = theBmp
      )
   )

 createDialog vfbRoll 500 500 style:#(#style_resizing, #style_toolwindow, #style_titlebar, #style_sysmenu)

Gå tilbake til «Max scripts»

Hvem er online

Brukere i dette forumet: Ingen registrerte brukere og 1 gjest

cron