Collapse en animert mesh ??

Moderatorer: dboydesign, Super Moderatorer, Admins


Trådstarter
dronn1
Innlegg: 53
Registrert: lør 06 des, 2008
Sted: Ålesund
Kontakt:

Collapse en animert mesh ??

Legg innav dronn1 » ons 11 jan, 2012

Hei.

Har en del objekter/mesh som er animert. Disse vil jeg gjerne collapse til en editable poly, MEN jeg vil beholde animasjonen som er på de. Er også en del modifiers som feks, flex, turbosmth osv på noen av de.

Har sett litt på point cache, det funker, men da får jeg bare erstattet alle mine modifiers med en ny modifier, så da hjelper det meg ikke stort. :)

Noen som har peiling på hvordan dette kan gjøres ?

Altså, animert mesh -> editable poly (Med animasjon) :D

Takker for alle svar!
Jørgen Drønnen
3D Designer - Teknisk Tegner

Offshore Simulator Centre AS
http://www.offsim.no

Personlig Portfolio: www.DronnenDesign.com

Brukeravatar

Tronotrond
Innlegg: 3748
Registrert: lør 29 okt, 2005
Sted: Houston, TX
Kontakt:

Legg innav Tronotrond » ons 11 jan, 2012

Hm, er det et problem å ha Edit Poly med en Point Cache modifier?
Altså du eksporterer ut Point Cache animasjon først fra Edit Mesh'en. Kollapser/konverterer modellen til Edit Poly, legger på Point Cache modifier igjen og loader filen med animasjonsdataen..
TD/Technical Animator, Corporate Marketing - National Oilwell Varco, Houston, TX
Freelance 3D/VFX Artist - Hille3D

Brukeravatar

havards
Innlegg: 211
Registrert: ons 13 des, 2006

Legg innav havards » ons 11 jan, 2012

Du kan bake ned vertexanimasjonen fra pointcachen med litt maxscript action
02:14 Misfortune • hun skjuler så jævlig mye i smutthølet
http://folk.ntnu.no/havardsc/site/wordpress/


Trådstarter
dronn1
Innlegg: 53
Registrert: lør 06 des, 2008
Sted: Ålesund
Kontakt:

Legg innav dronn1 » tor 12 jan, 2012

havards skrev:Du kan bake ned vertexanimasjonen fra pointcachen med litt maxscript action


Hei.

Takk for svar.

Jo har sett på en del, men har ikke funnet noen som gjør akkurat det jeg ønsker. Har du noen forslag ? :)
Jørgen Drønnen

3D Designer - Teknisk Tegner



Offshore Simulator Centre AS

http://www.offsim.no



Personlig Portfolio: www.DronnenDesign.com


Trådstarter
dronn1
Innlegg: 53
Registrert: lør 06 des, 2008
Sted: Ålesund
Kontakt:

Legg innav dronn1 » tor 12 jan, 2012

Tronotrond skrev:Hm, er det et problem å ha Edit Poly med en Point Cache modifier?
Altså du eksporterer ut Point Cache animasjon først fra Edit Mesh'en. Kollapser/konverterer modellen til Edit Poly, legger på Point Cache modifier igjen og loader filen med animasjonsdataen..


Hei og takker for svar.

Ja det vil nok fungere, men jeg må ha en ren mesh, uten en eneste modifier.
Skal brukes i en real time visualisering/3d kart på nettet, og det programmet som skal brukes, Away 3D støtter visstnok bare ren mesh. :?
Jørgen Drønnen

3D Designer - Teknisk Tegner



Offshore Simulator Centre AS

http://www.offsim.no



Personlig Portfolio: www.DronnenDesign.com

Brukeravatar

havards
Innlegg: 211
Registrert: ons 13 des, 2006

Legg innav havards » fre 13 jan, 2012

Dette funket på en testscene til meg:

Kode: Velg alt

(
   fn bakePointCache obj start end =
   (
      pos = #();pos.count = obj.verts.count
      startT = timestamp()
      getVertMethod = polyop.getVert
      setVertMethod = polyop.setVert
      verts = #{1..obj.verts.count}
            
      animate on
         for t = start to end do
            at time t
            (
               for v = 1 to obj.verts.count do
                  pos[v] =  (getVertMethod obj v)
               setVertMethod obj verts pos
            )
            
      format "Time: % s.\n" ((timestamp() - startT) / 1000.0)

   )
   
   rollout rolBakePointCache "Bake point cache"
   (
      spinner spnStart "Start frame" range:[-1e3, 1e3, animationrange.start.frame] type:#integer fieldWidth:30
      spinner spnEnd "End frame" range:[-1e3, 1e3, animationrange.end.frame] type:#integer fieldWidth:30
      pickButton pBtnObject "Select object" across:2
      button btnBake "Bake" enabled:false
      label lblAuthor "havardsc@stud.ntnu.no"
      
      on pBtnObject picked obj do
      (
         pBtnObject.text = obj.name
         btnBake.enabled = true
      )
      
      on btnBake pressed do
         bakePointCache pBtnobject.object spnStart.value spnEnd.value
   )
   createDialog rolBakePointCache
)


Forutsetter at objektet er editable_poly og point cachen er en object space modifier og ikke world space.
02:14 Misfortune • hun skjuler så jævlig mye i smutthølet

http://folk.ntnu.no/havardsc/site/wordpress/


hardrock_ram
Innlegg: 1502
Registrert: ons 07 feb, 2007
Sted: Kristiansand

Legg innav hardrock_ram » lør 28 jan, 2012

Hva bruker du "format "Time: % s.\n" ((timestamp() - startT) / 1000.0)" til havards? :)
if your not living on a killing ground, you better make your own

Brukeravatar

havards
Innlegg: 211
Registrert: ons 13 des, 2006

Legg innav havards » søn 29 jan, 2012

Den måler hvor lang tid operasjonen tar, målt i sekunder.
02:14 Misfortune • hun skjuler så jævlig mye i smutthølet

http://folk.ntnu.no/havardsc/site/wordpress/


Gå tilbake til «Animering og rigging»

Hvem er online

Brukere i dette forumet: Ingen registrerte brukere og 1 gjest

cron